;       Type an AlphaWrite File  (works on V1.2)
;       Author Iain Fraser, Mortimer Technology Ltd, 1988
;
;       See AWUTIL.M68 for more info

       SEARCH  SYS
       SEARCH  SYSSYM
       SEARCH  TRM

       EXTERN  $ODTIM

       OBJNAM  .LIT

       VMAJOR  =1.
       VMINOR  =0
       VEDIT   =100.

       PHDR    -1,,PH$REE!PH$REU

WRID:
       BYP                                     ; strip leading spaces
       TRM                                     ; terminator on input line?
       BNE     PACKFL
       CRLF
       TYPECR  No filename supplied
       JMP     ENDEND
PACKFL:
       FSPEC   INFIL,WRT                       ; pack filename into DDB
       INIT    INFIL                           ; initialise DDB
       LOOKUP  INFIL                           ; file exists?
       BEQ     OPFIL
       CRLF
       TYPECR  File does not exist
       JMP     ENDEND
OPFIL:
       CLR     D2
       OPENI   INFIL
       LEA     A1,INFIL
INPB:   FILINB  INFIL
       TST     D.SIZ(A1)
       BEQ     ENDPRG
       CTRLC   ENDPRG
       ADD     #1,D2
       CMPB    D1,#^H00
       BNE     10$
       CMP     D2,#510.
       BLO     INPB
       MOVB    #^H0D,D1
       TTY
       MOVB    #^H0A,D1
       TTY
       BR      INPB
10$:    CMPB    D1,#^H7F
       BHI     INPB
       CMPB    D1,#^H20
       BLO     INPB
       TTY
       BR      INPB
ENDPRG:
       CLOSE   INFIL
ENDEND:
       CRLF
       EXIT

INFIL:  BLKB    D.DDB
       EVEN


       END

You are viewing proxied material from gopher.floodgap.com. The copyright of proxied material belongs to its original authors. Any comments or complaints in relation to proxied material should be directed to the original authors of the content concerned. Please see the disclaimer for more details.