1 REM ** WRITTEN BY MIKE SIGONA ON 3-7-77 **
2 REM ** REVISED ON 4-3-78 **
10 ?"PARAB":?:?
30 ?"THIS PROGRAM COMPUTES ALL PERTINENT INFORMATION AND AIDS IN"
35 ?"GRAPHING A PARABOLA, WHICH IS DEFINED BY y=Ax^2+Bx+C, A<>0."
100 SIGNIFICANCE 11
110 INPUT "ENTER A,B,C : ";A,B,C
130 IF A=0 THEN ? "DATA INVALID. A<>0. TRY AGAIN-":GOTO 110
140 ?:?"THE EQUATION IS y="A"x^2+"B"x+"C
150 h=-(B/(2*A))
160 p=1/(4*A)
170 k=((4*A*C)-B^2)/(4*A)
180 ?"THE PARABOLA OPENS ";
190 IF A<0 THEN ?"DOWNWARD." ELSE ?"UPWARD."
200 ?"THE COORDINATES OF THE VERTEX ARE (";h;",";k;")."
210 ?"THE AXIS OF SYMMETRY IS x=";h;"."
220 ?"THE COORDINATES OF THE FOCUS ARE (";h;",";k+p;")."
230 ?"THE EQUATION OF THE DIRECTRIX IS y=";k-p;"."
240 ?"THE FOCAL WIDTH IS";ABS(4*p);"."
245 ?"THE FOCAL LENGTH IS";p;"."
250 ?"THE LATUS RECTUM HAS END POINTS (";h-(2*p);",";k+p;") AND (";h+(2*p);",";k+p;")."
270 INPUT "TO PLOT POINTS, ENTER x COORDINATE (-999 IF STOP) : ";x
280 IF x=-999 THEN 500
290 y=A*x^2+B*x+C:?"y="y
300 ?"THE DISTANCE OF POINT (";x;",";y;") FROM THE DIRECTRIX IS";ABS(y-(k-p))
310 ?" AND THE DISTANCE TO THE FOCUS IS";SQR((x-h)^2+(y-(k+p))^2)
350 GOTO 270
500 ?:INPUT "DO YOU HAVE MORE DATA? ";A$
510 IF A$[1,1]="Y" THEN 110
