10 REM TOF (INSTR. & MAP)
20 ?TAB(-1,0);: REM CLEAR SCREEN
100 ?"ALPHA-BASIC DELETE 'REM' UTILITY"
110 ?" (COURTESY TETON DATA SYSTEMS)"
120 ?" (JACKSON, WYOMING)"
130 ?:?: INPUT "WANT INSTRUCTIONS (0 OR 1)? ";A
140 ?:?: IF A=0 GOTO PRGRM
150 ?" This program will go through your ALPHA-BASIC source file and"
160 ?"will delete all the 'REM' statements from the program, whether"
170 ?"they start a line or follow other program statements. Those"
180 ?"'REM' statements on a line alone will be deleted along with their"
190 ?"line number."
195 ?
200 ?" The program will create another file, named 'FILENAME.DEL' from"
210 ?"your 'FILENAME.BAS' source file, which will contain no 'REM' state-"
220 ?"ments. You can load a 'FILENAME.DEL' file in Basic, by executing a"
230 ?"'LOAD FILENAME.DEL' while in the command mode -- HANDY!!"
240 ?:?:?TAB(55);:INPUT "TYPE 'RETURN' TO RUN. ";A
1000 REM -----MAP VARIABLES-----
1010 STRSIZ 80
1020 MAP1 WORK'AREA
1030 MAP2 SOURCE'LIN,S,80
1040 MAP2 NAME$,S,20
1999 REM TOF (PROGRAM LOOP)
2000 PRGRM: INPUT "PROCESS WHICH FILENAME.BAS? "; NAME$
2010 LOOKUP NAME$+".BAS",CHK
2020 IF CHK=0 THEN PRINT NAME$;" NOT FOUND!": GOTO PRGRM
2030 OPEN #1, NAME$+".BAS", INPUT
2040 OPEN #2, NAME$+".DAT", OUTPUT
2050 LOOP: INPUT LINE #1, SOURCE'LIN
2060 IF EOF(1)=1 THEN GOTO FINISH
2070 IF INSTR(1,SOURCE'LIN,"REM TOF") <> 0 THEN GOTO WR'LIN
2080 PEEK=INSTR(1,SOURCE'LIN,"REM")
2090 IF PEEK=0 THEN GOTO WR'LIN ELSE GOTO DEL'REM
2100
2110 DEL'REM: A$=SOURCE'LIN
2120 FOR R=(PEEK-1) TO 1 STEP -1
2130 B$=MID(A$,R,1)
2140 IF B$=":" THEN SOURCE'LIN=LEFT(A$,R-1): GOTO WR'LIN
2150 NEXT R
2160 GOTO LOOP
2170
2180 WR'LIN: PRINT #2, SOURCE'LIN
2190 GOTO LOOP
2200
65000 FINISH: CLOSE #1: CLOSE #2
65010 ?:?:?"'REM' STATEMENTS DELETED FROM ";NAME$;".BAS!"
65020 ?"EXECUTE 'NEW' & 'LOAD' ";NAME$;".DAT TO RUN THE NEW FILE"
65030 ?"WITHOUT 'REM' STATEMENTS."
65040 ?:?:INPUT "ANOTHER TO RUN (0=NO 1=YES)? ";A
65050 IF A=1 THEN GOTO PRGRM
65060 END
