50 MAP1 W$(224),S,20
60 MAP1 F(224),F,6,0
65 STRSIZ 28
67 RANDOMIZE
70 PRINT" WELCOME TO THE SPANISH WORDGAME"
80 ?"DO YOU WANT INSTRUCTIONS? (YES/NO)"
85 INPUT A$
90 IF A$="N" OR A$="NO" THEN 352
95 ? TAB(-1,0) !CLEARS SCREEN
100 ?"IN THIS GAME YOU WILL HAVE TO GIVE THE SPANISH OR ENGLISH"
110 ?"TRANSLATION FOR THE WORD THE COMPUTER WILL GIVE YOU."
120 ?"FOR EXAMPLE,IF THE COMPUTER GIVES YOU THE WORD `CAT',YOU"
125 ?"HAVE TO TYPE `EL GATO'.AND IF THE COMPUTER GIVES YOU THE "
127 ?"WORD `EL GATO',YOU HAVE TO TYPE `CAT'."
130 ?"THE ENTIRE GAME HAS THREE PARTS,GOING FROM "
140 ?"EASY WORDS TO HARDER WORDS."
150 ?"SOME ITEMS ARE MORE THAN ONE WORD. ON EACH PART YOU WILL"
160 ?"HAVE TO MATCH SEVEN OUT OF TEN IN ORDER TO GO ON TO THE "
170 ?"NEXT PART. IF YOU FAIL TO DO THIS IN THE FIRST OR SECOND "
180 ?"PART, YOU WILL AUTOMATICALLY BE PUT OUT OF THE GAME."
190 ?"THE WORDS ARE CHOSEN AT RANDOM FROM LARGE FILES OF"
200 ?"LEXICAL ITEMS.IN SOME CASES A WORD OR PHRASE MAY HAVE "
210?"MORE THAN ONE MEANING, BUT ONLY ONE OF THEM HAS BEEN "
220 ?"ARBITRARILY CHOSEN FOR THE GAME."
225 INPUT "HIT RETURN TO CONTINUE"; AS$
227 ? TAB(-1,0)
280 ?"THE SCALE FOR THE SCORES IS AS FOLLOWS:"
290 ?" 15 - 20 _____________ POOR"
300 ?" 21 - 22 _____________ SO-SO"
310 ?" 23 - 24 _____________ FAIR"
320 ?" 25 - 26 _____________ GOOD"
330 ?" 27 - 28 _____________ VERY GOOD "
340 ?" 29 ________________ EXCELLENT"
350 ?" 30 ________________ SUPER!"
351 INPUT "HIT RETURN TO CONTINUE";AS$
352 ? TAB(-1,0)
354 ?"YOU HAVE THE CHOICE TO TRANSLATE FROM ENGLISH TO SPANISH OR "
355 ?"FROM SPANISH TO ENGLISH, OR BOTH WAYS."
357 ?"PLEASE,CHOOSE ONE OF THE THREE FOLLOWING INTEGERS 1,2,3"
360 ?" 1 : FROM ENGLISH TO SPANISH "
363 ?" 2 : FROM SPANISH TO ENGLISH "
365 ?" 3 : BOTH WAYS "
370 INPUT "YOUR CHOICE ";CH
375 IF CH<1 OR CH>3 THEN ?"AN INTEGER 1,2,3" :GOTO 352
380 Q=RND(1)
410 C1=0
420 C2=0
430 C3=0
440 REM C1 CTR FOR CORRECT ANSWER; C2 FOR TOTAL IN EACH SECTION;
450 REM C3 FOR TOTAL CORRECT ANSWERS
455 FOR L= 1 TO 224
460 F(L) = 0
470 NEXT L
480 REM F(L) IS FOR FLAGGING USED WORDS
490 FOR I= 1 TO 224
500 READ W$(I)
510 NEXT I
520 FOR J= 1 TO 10
530 IF C2<10 THEN 590
540 IF C2<20 THEN 570
550 Z=INT(156+ (67*RND(1) +1))
560 GOTO 600
570 Z=INT(78+ (77*RND(1) +1))
580 GOTO 600
590 Z=INT(77*RND(1) +1)
600 IF CH=1 AND INT(Z/2)=Z/2 THEN Z=Z+1
603 IF CH=2 AND INT(Z/2)<>Z/2 THEN Z=Z+1
605 IF F(Z)= 1 THEN 530
610 F(Z)=1
615 ? W$(Z)
620 C2 = C2+1
625 REM TEST FOR ODD OR EVEN Z
630 IF INT(Z/2)=Z/2 THEN 670
640 INPUT X$
645 F(Z+1)=1
650 IF X$<>W$(Z+1) THEN 730
660 GOTO 680
670 INPUT X$
674 F(Z-1)=1
675 IF X$<>W$(Z-1) THEN 730
680 ?"GOOD!"
690 C1=C1+1
710 C3=C3+1
720 GOTO 742
730 ?"THE CORRECT WORD IS: ";
733 IF INT(Z/2)=(Z/2) THEN 739
735 ?W$(Z+1); "__TYPE IT,PLEASE."
736 INPUT T$
737 IF T$=W$(Z+1) THEN 742
738 GOTO 730
739 ?W$(Z-1); "__TYPE IT,PLEASE."
740 INPUT T$
741 IF T$<>W$(Z-1) THEN 730
742 NEXT J
750 IF Z<=79 THEN 870
760 IF Z<=157 THEN 925
770 ?"YOUR SCORE FOR ALL THREE PARTS IS";C3
780 ?"YOUR RATING IS "
790 IF C3=30 THEN 1000
800 IF C3=29 THEN 1020
805 IF C3>=27 THEN 1040
810 IF C3>=25 THEN 1060
820 IF C3>=23 THEN 1080
830 IF C3>=21 THEN 1100
860 IF C3<20 THEN 1120
870 IF C3<7 THEN 5000
880 ?"YOU HAVE DONE THE FIRST PART"
890 ?"WITH";C1;"CORRECT ANSWERS"
900 ?"YOU WILL NOW GO ON TO THE SECOND PART"
910 C1=0
920 GOTO 520
925 IF C1<7 THEN 5000
930 ?"CONGRATULATIONS!! YOU HAVE DONE THE SECOND PART"
940 ?"WITH";C1;"CORRECTLY ANSWERED !"
950 ?"YOU WILL NOW GO ON TO THE THIRD PART"
960 C1=0
970 GOTO 520
1000 ?"SUPER!!!!!!!!"
1010 GOTO 1140
1020 ?"EXCELLENT"
1030 GOTO 1140
1040 ?"VERY GOOD!"
1050 GOTO 1170
1060 ?"GOOD!"
1070 GOTO 1170
1080 ?"FAIR"
1090 GOTO 1170
1100 ?"SO-SO"
1110 GOTO 1170
1120 ?"POOR"
1130 GOTO 1170
1140 ?"NOT TOO BAD !"
1150 ?"COME BACK AND PLAY AGAIN SOME TIME.
1160 GOTO 5050
1170 ?"YOU CAN DO BETTER! COME BACK AND PLAY"
1180 ?"AGAIN SOME TIME."
1190 GOTO 5050
2000 DATA BROTHER,EL HERMANO,SISTER,LA HERMANA,WEEK,LA SEMANA,STUDENT
2010 DATA EL ALUMNO,LAST NAME,EL APELLIDO,HOUSE,LA CASA,CAR,EL COCHE
2020 DATA MONEY,EL DINERO,MAN,EL HOMBRE,LADY,LA MUJER,HAND,LA MANO
2030 DATA PAPER,EL PAPEL,CHAIR,LA SILLA,WINDOW,LA VENTANA,MILK,LA LECHE
2040 DATA GRANDPARENTS,LOS ABUELOS,DOWNTOWN,EL CENTRO,MOVIES,EL CINE,NURSE
2050 DATA LA ENFERMERA,WATER,EL AGUA,LETTER,LA CARTA,DINNER,LA CENA
2060 DATA BOOK,EL LIBRO,BOX,LA CAJA,NOTEBOOK,EL CUADERNO,PENCIL,EL LAPIZ
2100 DATA KEY,LA LLAVE,DOOR,LA PUERTA,CLOCK,EL RELOJ,CHRUCH,LA IGLESIA
2110 DATA DOCTOR,EL MEDICO,MARKET,EL MERCADO,STORE,LA TIENDA,BEACH,LA PLAYA
2120 DATA TICKET,EL BOLETO,AIRPLANE,EL AVION,LIBRARY,LA BIBLIOTECA
2125 DATA LUNCH,EL ALMUERZO,BREAKFAST,EL DESAYUNO
2130 DATA TO LOOK FOR,BUSCAR,TO LOOK AT,MIRAR,TO NEED,NECESITAR,TO HAVE
3000 DATA TENER,"TO BE-TEMP.",SER,"TO BE-PERM.",ESTAR,TO GO,IR,TO TALK,HABLAR
3010 DATA TO SING,CANTAR,TO DANCE,BAILAR,TO BUY,COMPRAR,TO LISTEN,ESCUCHAR
3020 DATA TO STUDY,ESTUDIAR,TO CARRY,LLEVAR,TO WASH,LAVAR,TO DRIVE,MANEJAR
3030 DATA TO SELL,VENDER,TO EAT,COMER,TO READ,LEER,TO RAISE,LEVANTAR,TO PAY
3040 DATA PAGAR,TO TRAVEL,VIAJAR,TO TELL,DECIR,TO LEARN,APRENDER,TO MAKE;DO
3050 DATA HACER,TO DRINK,BEBER,TO WRITE,ESCRIBIR,TO BEGIN,EMPEZAR,TO END
3060 DATA TERMINAR,TO ARRIVE,LLEGAR,TO LEAVE,SALIR,TO CATCH,COGER,TO WAIT
3070 DATA ESPERAR,TO WORK,TRABAJAR,TO KNOW,SABER,TO WANT,DESEAR
3100 DATA TO UNDERSTAND,COMPRENDER,TO LIVE,VIVIR,TO SEE,VER
3105 DATA OPEN YOUR BOOKS
3110 DATA ABRAN LOS LIBROS,TELL ME IN SPANISH,DIGAME EN ESPANOL,READY,LISTOS
3120 DATA REPEAT,REPITAN,HOW,COMO,LOUDER,MAS ALTO,SLOWER,MAS DESPACIO
3130 DATA AGAIN,OTRA VEZ,I DON'T KNOW,NO SE,GOOD DAY,BUENOS DIAS
4000 DATA GOOD AFTERNOON,BUENAS TARDES,GOOD EVENING,BUENAS NOCHES
4010 DATA HOW ARE YOU,COMO ESTA USTED,WHAT IS YOUR NAME,COME SE LLAMA
4020 DATA WHAT DAY IS IT,QUE DIA ES,WHAT TIME IS IT,QUE HORA ES,WHICH
4030 DATA CAUL,WHEN,CUANDO,WHAT,QUE,WHERE,DONDE,WHO,QUIEN,TO WHERE,A DONDE
4040 DATA FROM WHERE,CUANTO,BECAUSE,PORQUE,WHY,POR QUE,AT WHAT TIME
4050 DATA A QUE HORA,HOW DO YOU SAY,COMO SE DICE,"I'M SORRY",LO SIENTO
4060 DATA EVERY DAY,TODOS LOS DIAS,AS USUAL,COMO SIEMPRE,"IT'S 1:00"
4070 DATA ES LA UNA,"IT'S 2:00",SON LAS DOS,"IT'S 2:15",SON LAS DOS Y CUARTO
4080 DATA "IT'S 3:30",SON LAS TRES Y MEDIA
5000 ?"YOU HAVE GOTTEN LESS THAN SEVEN CORRECT!"
5005 IF C2>10 THEN 5015
5012 GOTO 5025
5015 ?"ON THE SECOND PART"
5025 ?"GO HOME AND TRY AGAIN SOME OTHER DAY!"
5050 END
