80 RANDOMIZE
90 STRSIZ 10
100 DIM N$(20),T(20)
110 INPUT "WOULD YOU LIKE INSTRUCTIONS ";A$
120 IF LEFT$(A$,1)="Y" THEN GOSUB 600
130 ?:?TAB(-1,0)
140 INPUT "WHAT WILL BE THE WINNING SCORE ";WP
150 ?
160 INPUT "HOW MANY WILL BE PLAYING ";NP
170 GOSUB 500 !INITALIZE ROUTINE
180 P=1
190 ?TAB(-1,0);
200 ?"OK ";N$(P);" YOUR UP. YOU CURRENTLY HAVE A SCORE OF ";T(P);"."
210 A$="Y"
220 INPUT "DO YOU WANT TO ROLL ";A$
230 IF LEFT$(A$,1)="N" THEN GOTO 270
240 GOSUB 800 ! ROLL THE DICE
242 IF R=0 THEN 290 ! YOU HAVE BEEN SKUNKED
245 IF T(P)+R>=WP THEN 1200
250 GOSUB 400 !SCORE REPORT
260 GOTO 220
270 T(P)=T(P)+R
280 R=0
290 P=P+1 !GET NEXT PLAYER
300 IF P>NP THEN P=1
310 IF P=1 THEN GOSUB 460 !PRINT ALL PLAYERS SCORES
320 GOTO 190
400 REM****** SCORE REPORT ROUTINE *****
410 ?:?
420 ?"ALL RIGHT ";N$(P);" YOU HAVE ";R;" POINTS THIS ROUND AND"
430 ?T(P)+R;" FOR THE GAME. YOU ARE ONLY ";WP-(T(P)+R);" POINTS AWAY"
440 ?"FROM WINNING THE GAME."
450 RETURN
460 REM ***** ALL PLAYER SCORE ROUTINE ********
462 ?TAB(-1,0);
465 ?"HERE ARE THE CURRENT GAME SCORES "
470 ?
475 FOR I=1 TO NP
480 ?N$(I);" HAS ";T(I);" POINTS."
485 NEXT I
490 INPUT "PRESS `RETURN' TO CONTINUE.";A$
495 RETURN
500 REM****** INITALIZE ROUTINE ******
510 FOR I=1 TO NP
520 ?"NAME OF PLAYER NO. ";I;" ";
530 INPUT N$(I)
540 T(I)=0
550 NEXT I
560 R=0
570 RETURN
600 REM ****** INSTRUCTIONS FOR SKUNK ****
610 ?TAB(-1,0);
620 ?"THIS IS THE GAME OF SKUNK. THE OBJECT IS TO REACH THE SCORE"
630 ?"SET AS THE WINNING SCORE BY ROLLING THE DICE AND AVOIDING BEING"
640 ?"SKUNKED. YOU CAN ROLL THE DICE AS MANY TIMES AS YOU LIKE, BUT"
650 ?"IF YOU ROLL A SKUNK YOU LOSE ALL THE POINTS FOR THAT TURN. IF"
660 ?"YOU ROLL TWO SKUNKS YOU LOSE ALL THE POINTS YOU HAVE ACCUMULATED"
670 ?"THIS TURN AND ALL THE POINTS YOU HAD SO FAR IN THE GAME. TO"
680 ?"TO AVOID ROLLING A SKUNK YOU MAY STOP AT ANY TIME BY ANSWERING"
690 ?"`NO' TO THE QUESTION `WOULD YOU LIKE TO ROLL?'."
700 ?:?"BEFORE WE BEGIN PLEASE ENTER WHAT THE WINNING SCORE WILL BE"
710 ?"AND THE NUMBER OF PEOPLE WHO WILL BE PLAYING. THEN ENTER EACH"
720 ?"PLAYERS FIRST NAME, WHEN I ASK FOR IT.":?:?
730 INPUT "PRESS `RETURN' TO CONTINUE";A$
740 RETURN
800 REM **** ROLL THE DICE *********
810 R1=INT(6*RND(0)+1)
820 R2=INT(6*RND(0)+1)
830 ?:?
840 IF R1=1 THEN PRINT " SKUNK", ELSE PRINT " ";R1,
850 IF R2=1 THEN PRINT " SKUNK" ELSE PRINT " ";R2
860 J=1
870 IF R1=1 OR R2=1 THEN J=2
880 IF R1=1 AND R2=1 THEN J=3
890 ON J GOTO 900,950,1000
900 TR=R1+R2
910 R=R+TR
920 RETURN
950 REM******* SINGLE SKUNK *****
960 ?"SORRY ";N$(P);" BUT YOU ROLLED A SKUNK. YOU LOSE YOUR ";R
970 ?"POINTS FOR THIS TURN."
980 R=0
985 INPUT "PRESS `RETURN' TO CONTINUE.";A$
990 RETURN
1000 REM***** DOUBLE SKUNK ROUTINE *******
1010 ?:?
1020 ?"BAD NEWS ";N$(P);" YOU ROLLED A DOUBLE SKUNK."
1030 ?"YOU JUST BLEW ";T(P)+R;" POINTS."
1040 ?"BETTER LUCK NEXT TIME AROUND."
1050 R=0
1060 T(P)=0
1065 INPUT "PRESS `RETURN' TO CONTINE.";A$
1070 RETURN
1200 REM***** WINNING ROUTINE *******
1210 FOR J=1 TO 3
1220 ?CHR$(7);
1230 FOR I=1 TO 500:NEXT I
1240 NEXT J
1250 ?"CONGRADULATIONS ";N$(P);" YOU HAVE WON THE GAME!!!"
1260 ?"YOU HAD ";T(P)+R;" OF THE ";WP;" NEEDED."
1270 ?:?
1280 INPUT "WOULD YOU LIKE TO PLAY AGAIN? ";A$
1290 IF LEFT$(A$,1)="Y" THEN 110
1300 ?:?
1310 ?"WELL, BYE FOR NOW. COME BACK WHEN YOU FEEL LUCKY."
1320 ?"WATCH OUT FOR THE SKUNK, HE COULD GET YOU AT ANY TIME."
1330 END
