1 RANDOMIZE
5 REM *** WRITTEN BY TOM KARZES, CURTIS JR. HI SCHOOL, SUDBURY, MASS
6 REM *** MODIFIED BY DAVE AHL, DIGITAL
7 STRSIZ 64
8 A=0 : B=0 : C=0 : G=0
10 ? "YOU ARE IN A LARGE, NEW GOVERNMENT BUILDING WITH 1,000,000"
20 ? "ROOMS IN IT. THE BUILDING IS 100 ROOMS LONG, 100 ROOMS"
30 ? "WIDE, AND 100 ROOMS HIGH. A MAD BOMBER HAS HIDDEN A BOMB IN"
40 ? "ONE OF THE ROOMS AND HAS JUST PHONED A THREAT THAT THE BOMB IS"
50 ? "SET TO GO OFF IN 200 SECONDS FORTUNATELY, YOU HAPPEN TO HAVE"
60 ? "BOMB-TRACKER THAT SENDS OUT SIGNALS THAT GET STRONGER AS YOU"
70 ?"GET CLOSER TO THE BOMB. YOU ARE STARTING IN ROOM 0,0,0 AND"
80 ? "IT TAKES TEN SECOND TO MOVE TO ANY OTHER ROOM":?
90 ?:? "HIT RETURN TO START":INPUT LINE W
100 RANDOMIZE:A=INT(100*RND(0)):B=INT(100*RND(0)):C=INT(100*RND(0))
110 IF A=0 AND B=0 AND C=0 THEN 100
120 P1=A/100+B+C*100
125 ? "SIGNAL","CURRENT ROOM","SECONDS","COORDINATES FOR"
130 ? "STRENGTH","L, W, H,","ELAPSED","SEARCH (L,W,H)"
132 B$= " ####.## ## ## ## ### "
135 PRINT USING B$,10000-ABS(P1-P),D,E,F,G;
140 INPUT D,E,F:G=G+10:P=D/100+E+F*100:IF P=P1 THEN 170
145 IF G=200 THEN 150 ELSE GOTO 180
147 ?
150 ? "BOOOOOM!!!!!"
151 FOR N=1 TO 50
152 ? "!#$&&$%++*[][]%\%\/&'(()((<><>)<($%&#$!**+[]";
153 NEXT N
155 ?: INPUT "DO YOU WANT TO PLAY AGAIN (YES OR NO) ?";A$
160 IF A$="NO" THEN 999 ELSE GOTO 1
170 ? "BOMB DEACTIVATED IN ";G;"SECONDS. GOOD JOB!": GOTO 155
180 IF D>99 OR E>99 OR E<0 THEN 200
190 IF F>99 THEN 220 ELSE IF F<0 THEN 230 ELSE GOTO 135
200 ? "YOU WALKED OUT A WINDOW ON THE";:IF F<4 THEN 240
201 ? F;"TH FLOOR!!!"
202 ? "YOU WERE KILLED AND";200-G;"SECONDS LATER THE BUILDING"
203 ? "BLEW UP!!!":?: GOTO 155
220 ? "YOU ARE NOW";F*9;"FEET IN THE AIR!!":GOTO 202
230 ? "YOU ARE NOW";F*9;"FEET UNDERGROUND!!": GOTO 202
240 ON F GOTO 250,260,270
250 ? " 1ST FLOOR!!!": GOTO 202
260 ? " 2ND FLOOR!!!": GOTO 202
270 ? " 3RD FLOOR!!!": GOTO 202
999 END
