/*      $NetBSD: start.S,v 1.23 2011/03/26 15:49:26 tsutsui Exp $       */

/*-
* Copyright (c) 1999 The NetBSD Foundation, Inc.
* All rights reserved.
*
* This code is derived from software contributed to The NetBSD Foundation
* by Jonathan Stone, Michael Hitch and Simon Burge.
*
* Redistribution and use in source and binary forms, with or without
* modification, are permitted provided that the following conditions
* are met:
* 1. Redistributions of source code must retain the above copyright
*    notice, this list of conditions and the following disclaimer.
* 2. Redistributions in binary form must reproduce the above copyright
*    notice, this list of conditions and the following disclaimer in the
*    documentation and/or other materials provided with the distribution.
*
* THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
* ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
* TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
* PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
* BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
* CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
* SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
* INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
* CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
* ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
* POSSIBILITY OF SUCH DAMAGE.
*/

/*
* Copyright (c) 1992, 1993
*      The Regents of the University of California.  All rights reserved.
*
* This code is derived from software contributed to Berkeley by
* Ralph Campbell.
*
* Redistribution and use in source and binary forms, with or without
* modification, are permitted provided that the following conditions
* are met:
* 1. Redistributions of source code must retain the above copyright
*    notice, this list of conditions and the following disclaimer.
* 2. Redistributions in binary form must reproduce the above copyright
*    notice, this list of conditions and the following disclaimer in the
*    documentation and/or other materials provided with the distribution.
* 3. Neither the name of the University nor the names of its contributors
*    may be used to endorse or promote products derived from this software
*    without specific prior written permission.
*
* THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
* ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
* IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
* ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
* FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
* DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
* OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
* HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
* LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
* OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
* SUCH DAMAGE.
*
*      @(#)start.s     8.2 (Berkeley) 1/21/94
*/

/*
* start.s -
*
*     Contains code that is the first executed at boot time.
*
*      Copyright (C) 1989 Digital Equipment Corporation.
*      Permission to use, copy, modify, and distribute this software and
*      its documentation for any purpose and without fee is hereby granted,
*      provided that the above copyright notice appears in all copies.
*      Digital Equipment Corporation makes no representations about the
*      suitability of this software for any purpose.  It is provided "as is"
*      without express or implied warranty.
*
* from: Header: /sprite/src/boot/decprom/ds3100.md/RCS/start.s,
*      v 1.1 90/02/16 16:19:39 shirriff Exp  SPRITE (DECWRL)
*/

#include <mips/asm.h>
#include <mips/cpuregs.h>
#include <machine/dec_prom.h>

       .extern callv, 4

       .globl  start
start:
       .set    noreorder
#ifdef __GP_SUPPORT__
       la      gp, _C_LABEL (_gp)
#endif
       la      sp, start - CALLFRAME_SIZ
       sw      zero, CALLFRAME_RA(sp)          # Zero out old ra for debugger
       sw      zero, CALLFRAME_SP(sp)          # Zero out old fp for debugger
       move    s0, a0                          # save argc
       move    s1, a1                          # save argv
       beq     a2, DEC_REX_MAGIC, 1f           # jump if boot from DS5000
        move   s3, a3                          # BDslot: save call vector
       la      s3, _C_LABEL(callvec)           # init call vector
1:
       la      a0, _C_LABEL (edata)            # clear BSS
       move    a1, zero
       la      a2, _C_LABEL (end)
       jal     _C_LABEL(memset)                # memset(edata, 0, end - edata)
        subu   a2, a2, a0
       sw      s3, _C_LABEL(callv)             # save call vector
       move    a0, s0                          # restore argc
       jal     _C_LABEL(main)                  # main(argc, argv)
        move   a1, s1                          # restore argv
       j       _C_LABEL(prom_restart)          # restart...
        nop

       .set    reorder         # make as(1) handle hazard and BDslot
LEAF(prom_restart)
XLEAF(_rtt)
       lw      v0, _C_LABEL (callv)
       lw      v0, 0x9C(v0)                    /* halt */
       move    a0, zero                        /* Don't print anything. */
       move    a1, zero
       j       v0
END(prom_restart)

LEAF(prom_open)
       li      v0, DEC_PROM_OPEN
       j       v0
END(prom_open)

#ifndef LIBSA_NO_DEV_CLOSE
LEAF(prom_close)
       li      v0, DEC_PROM_CLOSE
       j       v0
END(prom_close)
#endif

LEAF(prom_lseek)
       li      v0, DEC_PROM_LSEEK
       j       v0
END(prom_lseek)

LEAF(prom_read)
       li      v0, DEC_PROM_READ
       j       v0
END(prom_read)

LEAF(prom_write)
       li      v0, DEC_PROM_WRITE
       j       v0
END(prom_write)