% The Computer Modern Roman family of fonts (by D. E. Knuth, 1979--1985)

if ligs>1: font_coding_scheme:="TeX text";
spanish_shriek=oct"074"; spanish_query=oct"076";
else: font_coding_scheme:=if ligs=0: "TeX typewriter text"
 else: "TeX text without f-ligatures" fi;
spanish_shriek=oct"016"; spanish_query=oct"017"; fi

mode_setup; font_setup;

input romanu;  % upper case (majuscules)
input romanl;  % lower case (minuscules)
input greeku;  % upper case Greek letters
input romand;  % numerals
input romanp;  % ampersand, question marks, currency sign
input romspl;  % lowercase specials (dotless \i, ligature \ae, etc.)
input romspu;  % uppercase specials (\AE, \OE, \O)
input punct;  % punctuation symbols common to roman and italic text
input accent;  % accents common to roman and italic text

marginchar=128;

if ligs>1: input romlig; fi  % letter ligatures
if ligs>0: input ocomlig; fi  % ligatures common with italic text
if ligs<=1: input romsub; fi  % substitutes for ligatures

ligtable "!": "`" =: spanish_shriek, marginchar kern -(5u#+width_adj#);
ligtable "?": "`" =: spanish_query,  marginchar kern -8.5u#;
ligtable ":": marginchar kern -5u#;
ligtable ";": marginchar kern -5u#;
ligtable marginchar: "`" kern -5u#, oct"134" kern -(7u#+max(2u#,dot_size#));

font_slant slant; font_x_height x_height#;
if monospace: font_normal_space 9u#; % no stretching or shrinking
font_quad 18u#;
font_extra_space 9u#;
else: font_normal_space 6u#+2letter_fit#;
font_normal_stretch 3u#; font_normal_shrink 2u#;
font_quad 18u#+4letter_fit#;
font_extra_space 2u#;
k#:=-.5u#; kk#:=-1.5u#; kkk#:=-2u#; % three degrees of kerning
ligtable "k": if serifs: "v": "a" kern -u#, fi\\"w": "e" kern k#,
 "a" kern k#, "o" kern k#, "c" kern k#;
ligtable "P": "A" kern kk#,
 "y": "o" kern k#, "e" kern k#, "a" kern k#, "." kern kk#, "," kern kk#;
ligtable "F": "V": "W": if serifs: "o" kern kk#, "e" kern kk#, "u" kern kk#,
   "r" kern kk#, "a" kern kk#, "A" kern kkk#,
  else: "o" kern k#, "e" kern k#, "u" kern k#,
   "r" kern k#, "a" kern k#, "A" kern kk#, fi
 "K": "X": "O" kern k#, "C" kern k#, "G" kern k#, "Q" kern k#;
ligtable "T": "y" kern if serifs: k# else: kk# fi,
 "Y": "e" kern kk#, "o" kern kk#,
  "r" kern kk#, "a" kern kk#, "A" kern kk#, "u" kern kk#;
ligtable "O": "D": "X" kern k#, "W" kern k#, "A" kern k#,
  "V" kern k#, "Y" kern k#;
if serifs: ligtable "h": "m": "n":
  "t" kern k#, "u" kern k#, "b" kern k#, "y" kern k#, "v" kern k#, "w" kern k#;
 ligtable "c": "h" kern k#, "k" kern k#; fi
ligtable "o": "b": "p": "e" kern -k#, "o" kern -k#, "x" kern k#,
  "d" kern -k#, "c" kern -k#, "q" kern -k#,
 "a": if serifs: "v" kern k#, "j" kern u#, else: "r" kern k#, fi
 "t": "y" kern k#,
 "u": "w" kern k#;
ligtable "A": if serifs: "R": fi\\ "t" kern k#,
 "C" kern k#, "O" kern k#, "G" kern k#, "U" kern k#, "Q" kern k#,
 "L": "T" kern kk#, "Y" kern kk#, "V" kern kkk#, "W" kern kkk#;
ligtable "g": "j" kern -k#; % logjam
ligtable "I": "I" kern -k#; fi % Richard III
% there are ligature/kern programs for |"f"| in the {\tt romlig} file
% and for |"-"|, |"`"|, and |"'"| in the {\tt comlig} file
bye.