rem ... The "subroutine batch" called from TEXSET.BAT
rem ................................. running menu:
:menu
%RAM%\mnu %RAM%\cfg.mnu %RAM%\envir.bat %RAM%\dos.bat %RAM%\mfbat.bat
call %RAM%\envir
rem ................................. chose process:
if errorlevel 255 goto syserr
if errorlevel 235 goto spell
if errorlevel 233 goto EXview
if errorlevel 232 goto EXtex
if errorlevel 231 goto EXedit
if errorlevel 169 goto load
if errorlevel 168 goto save
if errorlevel 151 goto parmf
if errorlevel 141 goto cstocs
if errorlevel 131 goto others
if errorlevel 125 goto dosbat
if errorlevel 124 goto archive
if errorlevel 52 goto metafont
if errorlevel 41 goto prints
if errorlevel 38 goto usercom
if errorlevel 36 goto tie
if errorlevel 34 goto specEd
if errorlevel 33 goto view
if errorlevel 32 goto TeX
if errorlevel 31 goto edit
if errorlevel 29 goto quit
if errorlevel 27 goto editor
if errorlevel 26 goto shell
if errorlevel 24 goto clear
goto quit
rem ................................. running Edit -> TeX -> View:
:edit
%EDIT% %WORK%.tex %EDITPAR%
set EDITPAR=
set MNU=32
goto menu
:TeX
set MNU=33
call %RAM%\texrun %MAIN% tex
goto menu
:View
%TEXDIR%\dvidrv dviscr @scr.cnf %SCROPT% %MAIN%
set MNU=31
goto menu
:specEd
%EDIT% %MARK%
set MNU=32
goto menu
:editor
%EDIT% %F3FILE%
goto menu
rem ................................. Experiment:
:EXedit
%EDIT% %MAIN%.try %EDITPAR%
set EDITPAR=
set MNU=232
goto menu
:EXtex
set MNU=233
call %RAM%\texrun %MAIN% try
goto menu
:exView
%TEXDIR%\dvidrv dviscr @scr.cnf %SCROPT% %MAIN%
set MNU=231
goto menu
rem ................................. others bats:
:prints
call %TEXDIRCFG%\prints
goto menu
:others
call %TEXDIRCFG%\others
goto menu
:metafont
if not exist %TEXDIRCFG%\metafont.bat goto sorry
call %TEXDIRCFG%\metafont
goto menu
rem ................................. correction of document:
:spell
if not exist %TEXDIR%\cstug\velky.%MARK% goto sorry
if %MARK%==ces set MARK=C
if %MARK%==slv set MARK=S
if %MARK%==ang set MARK=A
%TEXDIR%\cstug\texspell %WORK%.tex =%MARK% %SPELLOPT%
set MNU=32
goto menu
:tie
%TEXDIR%\vlnka %WORK%.tex
set MNU=32
goto menu
:usercom
%COMSPEC% /c %USERCOM%
goto menu
:cstocs
if errorlevel 141 set MARK=-i1 -o0
if errorlevel 142 set MARK=-i0 -o1
if errorlevel 143 set MARK=-i2 -o0
if errorlevel 144 set MARK=-i0 -o2
if errorlevel 145 set MARK=-i1 -o2
if errorlevel 146 set MARK=-i2 -o1
echo CSTOCS %MARK% %WORK%.tex
%TEXDIR%\cstocs %MARK% %WORK%.tex
if errorlevel 1 %COMSPEC% /c pause
set MNU=31
goto menu
rem ................................. Special functions:
:dosbat
set MNU=25
@echo on
@call %RAM%\dos
@echo off
goto menu
:clear
if not %MAIN%==%WORK% echo delete %WORK%.bak
if not %MAIN%==%WORK% del %WORK%.bak
echo delete %MAIN%.bak %MAIN%.log %MAIN%.dvi %MAIN%.aux %MAIN%.lq %MAIN%.hp %MAIN%.fx
for %%f in (bak log dvi aux lq hp fx) do del %MAIN%.%%f
goto menu
:shell
echo Quit the shell to return to TEX-MENU-SYSTEM.
%SHELL%
goto menu
:parmf
set MNU=152
goto menu
:save
set > %RAM%\file.mnu
echo echo **** CONFIGURATION from file %MARK%.bat **** > %MARK%.bat
dupcent %RAM%\file.mnu set >> %MARK%.bat
echo set MNU=31 >> %MARK%.bat
del %RAM%\file.mnu
set mnu=65
goto menu
:load
set MNU=66
call %MARK%
goto menu
rem ................................. Sorry
:sorry
%RAM%\mnu %TEXDIRCFG%\sorry.mnu
goto menu
rem ................................. Diskette:
:archive
if %AR%==from goto fromdisc
echo copy %D%:%MAIN%.tex
copy %D%:%MAIN%.tex
if not %WORK%==%MAIN% echo copy %D%:%WORK%.tex
if not %WORK%==%MAIN% copy %D%:%WORK%.tex
set MNU=31
goto menu
:fromdisc
echo copy %MAIN%.tex %D%:
copy %MAIN%.tex %D%:
if not %MAIN%==%WORK% echo copy %WORK%.tex %D%:
if not %MAIN%==%WORK% copy %WORK%.tex %D%:
set MNU=31
goto menu
rem ................................. Final:
:syserr
echo SORRY - Error in configuration of TeX system.
echo Please ask the system engineer to solve this problem.
:quit
%KBD% %TEXDIR%\kbd /u
%LASTCOM%
