%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%                                                            %
%                VERSETZUNGSZEICHEN                          %
%                                                            %
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%



%%%%%%%%%%%%
%% "flat"  %
%%%%%%%%%%%%

beginchar(50, nhw#, 2nhh#, 2nhh#);
        clear;
        penpos4(7/24nhh, 30);%/5,20           %  1
        penpos3(nhh/5,-90);%/5,20             %
        penpos2(nhh/5, 90);%/5,20             %
        y1 =  h;                              %4
        x1 = x2 = x3 = s; x4 = w-s;           %  2
        y4 = s;                            %
        y2l - y3r =  1/4h; y2l = 0;           %  3
        currentpen:= pencircle scaled 3thinwidth;
        penstroke  z2e...z4e...z3e{sw};%right ,sw
        draw z1--z3;
        draw z1--z3;
penlabels(1,2,3,4);
endchar;

%%%%%%%%%%
%% "bb"  %
%%%%%%%%%%

beginchar(51,2nhw#, 2nhh#, 2nhh#);
        clear;
        penpos4(nhh/4,  0);%/5,20
        penpos3(nhh/4,-90);%/5,20
        penpos2(nhh/4, 90);%/5,20
        y1 =  h;                              %4
        x1 = x2 = x3 = s; x4 = w/2-s;         %  2
        y4 = s;                            %
        y2l - y3r =  1/4h; y2l = 0;           %  3
        currentpen:= pencircle scaled 3thinwidth;
        draw z1--z3;
        draw z1--z3;
        penstroke  z2e..z4e...z3e{sw};
        draw (z1--z3) shifted ((w/2 - 1.5s),0);
    penstroke (z2e..z4e...z3e{sw})shifted ((w/2 -1.5s),0);
endchar;

%%%%%%%%%%%%%
%% "sharp"  %
%%%%%%%%%%%%%

beginchar(52, nhw#, 1.5nhh#, 1.5nhh#);
        clear;
        penpos3(nhh/2,90);
        penpos4(nhh/2,90);
        y1 =  h - s; y1 - y2 = 2h - s;
        x1 = x2 =  s; z3 = (0,1/4nhh);
        y4l = y3r; x4 = w;
        currentpen:=  pencircle scaled 3thinwidth;
        draw z1--z2;
        draw (z1--z2) shifted (w-2s,s);
        penstroke  z3e--z4e;
        penstroke (z3e--z4e) shifted (0, -nhh);
penlabels(1,2,3,4);
endchar;

%%%%%%%%%%
%% "xx"  %
%%%%%%%%%%%

beginchar(53, nhw#,  .5nhh#,  .5nhh#);
        clear;
        z1 = (s, h-s); z2 = (w-s, h-s);
        z3 = (s,-h+s); z4 = (w-s,-h+s);
        currentpen:= pencircle scaled .2nhh;
        draw z1--z4; draw z3--z2;
        currentpen:= pencircle scaled .3nhh;
        drawdot z1; drawdot z2; drawdot z3; drawdot z4;
endchar;

%%%%%%%%%%%%%%%
%% "natural"  %
%%%%%%%%%%%%%%%

beginchar(54, nhw#, 1.5nhh#, 1.5nhh#);
        clear;
        penpos3(nhh/2,90);
        penpos4(nhh/2,90);
        y1 =  h;  y2 = -h + nhh/2;
        x1 = x2 =  s; z3l = (s,0);
        y4 = y3r; x4 = w-s;
        currentpen:= pencircle scaled 3thinwidth;
        draw z1--z2;
        draw (z1--z2) shifted (w-2s,-h+y4r);
        penstroke  z3e--z4e;
        penstroke (z3e--z4e) shifted (0, -nhh);
endchar;

%%%%%%%%%%%%%%%%
%% "1/4 flat"  %
%%%%%%%%%%%%%%%%

beginchar(55, nhw#, 2nhh#, 2nhh#);
        clear;
        penpos4(7/24nhh, 30);%/5,20           %  1
        penpos3(nhh/5,-90);%/5,20             %
        penpos2(nhh/5, 90);%/5,20             %
        y1 =  h;                              %         4
        x1 = x2 = x3 = w-s; x4 =2w-3s;        %  2
        y4 = s;                               %
        y2l - y3r =  1/4h; y2l = 0;           %  3
        currentpen:= pencircle scaled 3thinwidth;
        penstroke  (counterclockwise
        (z2e...z4e...z3e{sw}) reflectedabout(z1 ,z3));
        draw z1--z3;
        draw z1--z3;
penlabels(1,2,3,4);
endchar;

%%%%%%%%%%%%%%%%
%% "3/4 flat"  %
%%%%%%%%%%%%%%%%

beginchar(56, 2nhw#-2S, 2nhh#, 2nhh#);
        clear;
        penpos4(7/24nhh, 30);%/5,20           %  1
        penpos3(nhh/5,-90);%/5,20             %
        penpos2(nhh/5, 90);%/5,20             %
        y1 =  h;                              %         4
        x1 = x2 = x3 = w/2; x4 =w-s;          %  2
        y4 = s;                               %
        y2l - y3r =  1/4h; y2l = 0;           %  3
        currentpen:= pencircle scaled 3thinwidth;
        penstroke  z2e...z4e...z3e{sw};
        penstroke  (counterclockwise
        (z2e...z4e...z3e{sw}) reflectedabout(z1 ,z3));
        draw z1--z3;
        draw z1--z3;
penlabels(1,2,3,4);
endchar;