hebchar "The letter is `";
beginchar(224,14.4u#,ht#,0);      %letter ALEPH
 adjust_fit(0.1pt,0.1pt);
 pickup redis_pen;
 lft x1=x2=x3=leftstemloc;     rt x7=w-x2;
 x4=x1+over;                   x10+over=x9;
 x8=x9=x7-o;
 y3=y4;                        bot y3=0;
 y10=y9;                       top y10=h;
 bot y7=-o;                    top y1=h;
 y2=0.5h;                      y8=3/4h;
 z5=.25[z1,z7];                z6=.75[z1,z7];
 draw z1--z7;
 draw z5{dir -145}..{dir -100}z2--z3--z4;
 draw z10--z9--z8{dir -100}..{dir -145}z6;
endchar;


hebchar "The letter a";
beginchar(225,12.8u#,ht#,0);     %letter BETH
 adjust_fit(0.1pt,0.1pt);
 pickup redis_pen;
 x4=leftstemloc;  x5=w-x4;
 x1=x4+littlend;  x3=x2=x5-bigend;
 y4=y5=y3;        bot y4=0;
 y1=y2;           top y2=h;
 draw  z1--z2--z3; draw z4--z5;
 labels(1,2,3,4,5);
endchar;


hebchar "The letter b";
beginchar(226,10.12u#,ht#,0);     %letter GIMMEL
 adjust_fit(0.1pt,0.1pt);
 pickup redis_pen;
 x1=leftstemloc;  x6=x1+littlend;
 x2=w-x1;         x5=x6+over;
 bot y1=-o;
 y1=y2; y5=y6;    top y5=h;
 z3=0.5[z2,z5];
 draw  z2--z5--z6; draw  z1{dir 60}..{dir 10}z3;
endchar;


hebchar "The letter c";
beginchar(227,12.16u#,ht#,0);     %letter DALET
   adjust_fit(0.1pt,0.1pt);
pickup redis_pen;
 x1=leftstemloc;  x3=w-x1;
 x2=x4=x3-bigend;
 y1=y2=y3;        top y1=h;
 bot y4=-o;
 draw  z1--z3; draw z2--z4;
 labels(1,2,3,4);
endchar;


hebchar "The letter d";
beginchar(228,12.16u#,ht#,0);     %letter HEH
   adjust_fit(0.1pt,0.1pt);
pickup redis_pen;
 x1=leftstemloc;  x2=x3=w-x1;
 x4=x5=x1+littlend;
 y4=y3;           bot y4=-o;
 y1=y2;           top y2=h;
 y5=1/2*h;
 draw  z1--z2--z3; draw z4--z5;
 labels(1,2,3,4,5);
endchar;

hebchar "The letter e";
beginchar(229,5.4u#,ht#,0);     %letter VAV
   adjust_fit(0.1pt,0.1pt);
pickup redis_pen;
 x1=leftstemloc;  x2=x3=w-x1;
 y1=y2;           top y2=h;
 bot y3=-o;
 draw  z1--z2--z3;
 labels(1,2,3);
endchar;

hebchar "The letter f";
beginchar(230,8.10u#,ht#,0);     %letter ZAIN
   adjust_fit(0.1pt,0.1pt);
pickup redis_pen;
 x1=leftstemloc;  x3=w-x1;
 x2=x4=0.5*w;
 y1=y2=y3;        top y1=h;
 bot y4=-o;
 draw  z1--z3; draw z4--z2;
 labels(1,2,3,4);
endchar;

hebchar "The letter g";
beginchar(231,12.16u#,ht#,0);     %letter KHET
   adjust_fit(0.1pt,0.1pt);
pickup redis_pen;
 x1=leftstemloc;  x2=x3=w-x1;
 x4=x5=x1+littlend;
 y4=y3;           bot y4=-o;
 y1=y2=y5;        top y2=h;
 draw  z1--z2--z3; draw z4--z5;
 labels(1,2,3,4,5);
endchar;


hebchar "The letter h";
beginchar(232,14.16u#,ht#,0);     %letter TETT
   adjust_fit(0.1pt,0.1pt);
pickup redis_pen;
 x1=leftstemloc;    x6=x5=w-x1;
 x2=x3=x1+littlend; x7=0.5w;
 x4=x5-over;
 y1=y2=y7=y6;     top y1=h;
 y3=y5=5/17h;
 bot y4=-o;
 draw  z1--z2--z3..z4..z5--z6--z7;
 labels(1,2,3,4,5,6,7);
endchar;


hebchar "The letter i";
beginchar(233,6.8u#,ht#,0);     %letter YUD
   adjust_fit(0.1pt,0.1pt);
pickup redis_pen;
 x1=leftstemloc;  x2=x3=w-x1;
 y3=h*.5;
 y1=y2;           top y2=h;
 draw  z1--z2--z3;
endchar;
hebchar "The letter k";

beginchar(234,11.48u#,ht#,0);     %letter HAF
   adjust_fit(0.1pt,0.1pt);
pickup redis_pen;
 x1=leftstemloc;  x2=x3=w-x1;
 x4=x1+littlend;
 bot y2=0;
 y1=y2; y3=y4;    top y3=h;
 draw  z1--z2--z3--z4;
endchar;

hebchar "The letter j";
beginchar(235,8.8u#,ht#,depth#);  %letter KAF sofi
   adjust_fit(0.1pt,0.1pt);
pickup redis_pen;
 x1=leftstemloc;  x2=x3=w-x1;
 y1=y2;      top y1=h;
 bot y3=-o-d;
 draw z1--z2--z3;
endchar;

hebchar "The letter l";
beginchar(236,9.44u#,hm#,0);     %letter LAMED
   adjust_fit(0.1pt,0.1pt);
pickup redis_pen;
 x1=x2=leftstemloc;  x3=x4=w-x1;
 x5=x4-bigend;       x6=.5[x2,x3];
 top y1=h;
 y4=1/6h;            top y2=top y3=h-over;
 y5=y6+o;            bot y6=0;
 draw  z1--z2--z3--z4{dir-95}..{dir180}z5--z6;
 labels(1,2,3,4,5,6);
endchar;


hebchar "The letter n";
beginchar(237,14.16u#,ht#,0);     %letter MEM
   adjust_fit(0.1pt,0.1pt);
pickup redis_pen;
 x8=leftstemloc;  x3=x4=w-x8;
 x7=x6=x1=x8+bigend;
 x5=.5[x1,x3];    x2=x1+bigend;
 bot y2=0;        bot y1=-o;
 y3=y2;           top y5=h;
 y4=y6=10/17h;    y5=y8=y7;
 draw  z1--z6..z5..z4--z3--z2; draw  z6--z7--z8;
endchar;

hebchar "The letter m";
beginchar(238,12.8u#,ht#,0);     %letter MEM sofi
   adjust_fit(0.1pt,0.1pt);
pickup redis_pen;
 x1=leftstemloc;  x2=x5=x1+littlend;
 x3=x4=w-x1;
 y4=y5;           bot y4=0;
 y1=y2=y3;        top y2=h;
 draw  z1--z3--z4--z5--z2;
 labels(1,2,3,4,5);
endchar;

hebchar "The letter p";
beginchar(239,7.44u#,ht#,0);     %letter NOUN
   adjust_fit(0.1pt,0.1pt);
pickup redis_pen;
 x4=leftstemloc;  x3=w-x4;
 x1=x4+littlend;  x2=x3;
 y4=y3;           bot y4=0;
 y1=y2;           top y2=h;
 draw  z1--z2--z3--z4;
endchar;

hebchar "The letter o";
beginchar(240,5.4u#,ht#,depth#);   %letter NOUN sofi
   adjust_fit(0.1pt,0.1pt);
pickup redis_pen;
 x1=leftstemloc;  x2=x3=w-x1;
 y1=y2;      top y1=h;
 bot y3=-d-o;
 draw z1--z2--z3;
endchar;

hebchar "The letter q";
beginchar(241,12.8u#,ht#,0);     %letter SAMEKH
   adjust_fit(0.1pt,0.1pt);
pickup redis_pen;
 x1=leftstemloc;  x6=x5=w-x1;
 x2=x3=x1+littlend;
 x4=.5[x3,x5];
 y1=y2=y6;        top y1=h;
 y3=y5=5/17h;
 bot y4=-o;
 draw  z2--z3..z4..z5--z6--z1;
 labels(1,2,3,4,5,6);
endchar;

hebchar "The letter r";
beginchar(242,14.88u#,ht#,0);     %letter EIN
   adjust_fit(0.1pt,0.1pt);
pickup redis_pen;
 x1=leftstemloc;  x6=x1+littlend;
 x3=w-x1;         x4=x3-1.5*bigend;
 x5=x6+bigend;    x2=x5+littlend;
 bot y1=0;        top y5=h;
 y1+h/10=y2;      y5=y6=y4=y3;
 draw  z2--z5--z6; draw z4--z3..z2..{dir180}z1;
endchar;

hebchar "The letter t";
beginchar(243,12.16u#,ht#,0);     %letter PEH
   adjust_fit(0.1pt,0.1pt);
pickup redis_pen;
 x1=leftstemloc;  x2=x1+littlend;
 x4=x3;           x3=x2+littlend;
 x6=x7;           x6=w-x1;
 x5=x3+bigend;
 bot y1=0;        top y3=h;
 y7=y1;           y3=y2=y6;
 y5=y4;           y4=h*.5;
 draw  z1--z7--z6--z2; draw  z3--z4--z5;
endchar;

hebchar "The letter s";
beginchar(244,12.16u#,ht#,depth#);     %letter PEH sofi
   adjust_fit(0.1pt,0.1pt);
pickup redis_pen;
 x1=leftstemloc;
 x3=x4;           x3=x1+littlend;
 x6=x7;           x6=w-x1;
 x5=x3+bigend;
 bot y7=-d-o;
 y1=y3=y6;        top y3=h;
 y4=y5; y4=h*.5;
 draw  z1--z6--z7; draw  z3--z4--z5;
endchar;

hebchar "The letter is v";
beginchar(245,12.8u#,ht#,0);     %letter  TSADIk
   adjust_fit(0.1pt,0.1pt);
 pickup redis_pen;
 x5=leftstemloc;     x1=x5+littlend;
 x2=x1+bigend;       x6=x4=w-x5;
 x6=x7+bigend;       x3=8/14[x5,x6];
 y5=y4;              bot y4=0;
 y1=y2=y6=y7;        top y1=h;
 y3=.5h;
 draw  z1--z2{dir -90}..{dir -40}z4--z5;
 draw  z7--z6{dir -80}..{dir -200}z3;
endchar;


hebchar "The letter is u";
beginchar(246,11.52u#,ht#,depth#);     %letter  TSADIK sofi
   adjust_fit(0.1pt,0.1pt);
 pickup redis_pen;
 x1=leftstemloc;     x2=x3=x4=x1+bigend;
 x6=w-x1;            x5=x6-bigend;
 y1=y2=y5=y6;        top y1=h;
 bot y4=-d;      y3=6/16h;
 draw  z1--z2--z4;
 draw  z5--z6{dir -80}..{dir -190}z3;
endchar;

hebchar "The letter is w";
beginchar(247,12.16u#,ht#,depth#);     %letter  KUF
   adjust_fit(0.1pt,0.1pt);
 pickup redis_pen;
 x1=leftstemloc;     x2=x3=w-x1;
 x4-littlend=x5=7/15[x1,x2];
 x6=x7=x1+littlend;
 top y1=top y2=h;            y3=2.5/6h;
 y4=y5;              bot y5=0;
 y6=2/3h;            bot y7=-d-o;
 draw  z1--z2--z3{dir -100}..{dir -190}z4--z5;
 draw  z6--z7;
endchar;hebchar "The letter x";


beginchar(248,9.4u#,ht#,0);     %letter RESH
   adjust_fit(0.1pt,0.1pt);
 pickup redis_pen;
 x1=leftstemloc;  x2=x3=w-x1;
 y1=y2;           top y2=h;
 bot y3=-o;
 draw  z1--z2--z3;
 labels(1,2,3);
endchar;


hebchar "The letter y";
beginchar(249,17.6u#,ht#,0);     %letter SCHIN
   adjust_fit(0.1pt,0.1pt);
 pickup redis_pen;
 x1=leftstemloc;  x2=x1+bigend;
 x7=x2;           x6=w-x1;
 x4=.5*w;         x10=.5[x7,x9];
 x3=x4-littlend;  x5=x6-over;
 x6=x9;           x8=.5[x7,x4];
 bot y10=-o;      top y5=h;
 y1=y2=y5=y6=y4=y3;
 y7=y9=.3*h;      y8=y7+h/10;
 draw  z1--z2--z7..z10..z9--z6--z5; draw z3--z4{dir -d}..z8..z7;
endchar;



hebchar "The letter z";
beginchar(250,14.16u#,ht#,0);     %letter TAV
   adjust_fit(0.1pt,0.1pt);
 pickup redis_pen;
 x1=leftstemloc;  x5=x6=w-x1;
 x2=x3=x1+bigend; x4=x3-littlend;
 y1=y2;           bot y1=0;
 y3=y4=y5;        top y3=h;
 bot y6=-o;
 draw  z1--z2--z3; draw z4--z5--z6;
 labels(1,2,3,4,5,6);
endchar;

You are viewing proxied material from ftp.icm.edu.pl. The copyright of proxied material belongs to its original authors. Any comments or complaints in relation to proxied material should be directed to the original authors of the content concerned. Please see the disclaimer for more details.