"Le Scarabee et le Katana" by "Eric Forgeot".
The story creation year is 2007.
The release number is 3.
The story genre is "Fiction".
The story headline is "Une aventure rapide.".
The story description is "Un scarabee, une epee forgee pour le dieu des oceans, et eventuellement quelques asteroides. Speed-IF / Rapid'IF du 26 aout 2007 -
http://ifiction.free.fr".
Release along with cover art, a website, the source text, a file of "Fichier de jeu" called "otto_scarabeekatana.gblorb.blb", a file of "Version texte uniquement" called "otto_scarabeekatana.z8".
[Figure of Cover is the file "Cover.png".]
Figure of Nuit is the file "nuit.png".
Figure of Jour is the file "jour.png".
Sound of Intro is the file "scarabee_intro.ogg".
Sound of Perdu is the file "scarabee_perdu.ogg".
When play begins:
display the figure of Cover;
play the sound of Intro.
Include French by Eric Forgeot.
Part 1 - Mise en place des options
Chapter 1 - Les bases
Use full-length room descriptions.
Use no scoring.
A door is usually female. A door is seldom locked.
Chapter 2 - Les verbes generiques
Talking to is an action applying to one thing.
Carry out talking to:
say "Vous ne savez pas quoi dire.".
Understand "talk to [someone]" and "greet [someone]" and "speak to [someone]" and "parler avec [someone]" and "parler au [someone]" and "parler a [someone]" and "interroger [someone]" as talking to.
Understand the command "read" as something new.
Understand the command "lire" as something new.
Reading is an action applying to one thing.
Understand "read [something]" as reading.
Understand "lire [something]" as reading.
Carry out reading:
say "ll n'avait rien de special a lire ici.".
Understand the command "score" as something new. [a mistake ("Pas de score dans ce jeu.")]
[Understand "score" as a mistake ("Pas de score dans ce jeu."). : si on le laisse, commande chanter a la place]
Understand "info" and "informations" as a mistake ("Ce jeu realise avec la version experimentale d'Inform 7 en francais peut presenter certaines limitations dans le choix des verbes. Merci de faire vos remarques sur le forum
http://ifiction.free.fr")
Understand "aide" and "conseil" and "conseils" as a mistake ("Essayez de mediter sur les objets qui vous entourent, ils pourront peut-etre vous reveler quelques secrets. Sinon demandez la solution. De plus les adversaires a la fin seront plus facilement vaincus si vous etes le mieux arme possible.")
Understand "solution" and "walkthrough" as a mistake ("Voici une solution possible : [line break]x moi[line break]x paravent[line break]x panneaux[line break]x scarabee[line break]mediter sur scarabee[line break]mediter sur panneaux[line break]mediter sur armure[line break]mediter sur paravent[line break]enlever armure[line break]prendre le scarabee[line break]pousser panneau[line break]mettre scarabee dans l'ouverture[line break]fermer le panneau[line break]aller a droite[line break]prendre l'epee[line break]aller a gauche[line break]pousser le panneau[line break]prendre le scarabee[line break]mettre le scarabee sur kusanagi[line break]dormir[line break]mettre l'armure[line break]sortir[line break]descendre[line break]attaquer les ninjas [line break](et il a egalement une autre maniere de faire, en placant le scarabee sur le corps des compagnons sur les marches...)")
Understand "credits" and "credit" as a mistake ("Merci a Yoruk pour son beta-test detaille ainsi qu'aux membres de
http://ifiction.free.fr")
Chapter 3 - Les routines et les scenes
Taking inventory is acting confused. Looking is acting confused. Examining a thing is acting confused. Waiting is acting confused.
Talking to someone is acting confused.
The player has some text called mission. The mission of the player is "Votre mission actuelle est de rapporter l'epee de Kusanagi-no-Tsurugi a votre Shogun, quel qu'en soit le prix. Vous ne laisserez absolument personne se mettre en travers de votre chemin. Et surtout pas les vils ninjas du clan de Daimyo"
After acting confused for the fourth turn:
say "Vous vous rappelez ce qui vous amene ici... [mission of the player].".
Part 2 - Le jeu
Chapter 1 - Les lieux, le decor et l'histoire
Dedans is a region.
Dehors is a region.
Cage is a recurring scene. Cage begins when scarabee is inside cachette for the second turn. Cage ends when scarabee is in Temple.
Protege is a scene. Protege begins when play begins.
Protege ends when the player is in Dehors for the first turn and nuit is happening.
Traque is a scene. Traque begins when Protege ends.
Nuit is a scene. Nuit begins when play begins. Nuit ends when the player is asleep for the first turn.
Jour is a scene. Jour begins when Nuit ends.
[Every turn during Nuit:
if the player is in Dehors
begin;
say "Il fait nuit.";
otherwise;
say "";
end if.]
Combat is a scene. Combat begins when the player is in Foret for the second turn.
When combat begins:
say "L'affrontement commence... ";
try attacking ninjas.
A person is either awake or asleep. A person is usually awake.
Instead of sleeping when the player is in Dehors:
say "Cet endroit n'est pas le plus adapte ni le plus sur pour faire un petit somme...".
Instead of sleeping when the armure is worn:
say "Dormez-vous avec une armure de plate ? Le traditionalisme a ses limites tout de meme...".
Instead of sleeping during nuit: now the player is asleep; say "Vous vous endormez.";
if Traque is happening and (the katana is magic or fantomes are in parvis)
begin;
say "Vous vous reveillez quelques heures plus tard, avec l'impression d'avoir ete protege durant votre sommeil par des forces exterieures aux votres.";
otherwise;
if Traque is happening
begin;
say "Durant votre sommeil, vous ne faites pas attention aux tueurs de l'ombre qui entrent discretement dans le temple pour vous y enlever."; end the game in death;
play the sound of Perdu;
otherwise;
say "Vous vous reveillez quelques heures plus tard, en pleine forme.";
display the figure of Jour;
end if;
end if.
Table of Stress
evenement
"des pas sur le parvis du temple"
"un craquement dans le toit du temple"
"un cri etouffe au loin"
"un bruissement dans le feuillage des palmiers aux alentours"
"un bruit sourd"
When protege ends:
display the figure of Nuit;
say "Vous avez l'impression d'avoir vu bouger dans les ombres protegees par les arbres.".
Every turn during traque:
if a random chance of 20 in 100 succeeds
begin;
choose a random row in Table of Stress;
say "Vous avez l'impression d'avoir entendu [evenement entry].";
otherwise;
say "";
end if.
The CCombat is a number which vary. The CCombat is 10.
Every turn:
Now the CCombat is 10;
if the armure is worn, increase the CCombat by 2;
if the armure is not worn, decrease the CCombat by 1;
if traque is happening, decrease the CCombat by 1;
if the player is not carrying wakizashi, decrease the CCombat by 2;
if the player carries katana, increase the CCombat by 3;
if the katana is magic, increase the CCombat by 4;
if the fantomes are in parvis, increase the CCombat by 3.
Understand "CCombat" as a mistake ("Votre capacite de combat est de [CCombat].").
Temple is a room in dedans. The description of Temple is "[if not visited]Apres des jours de marche dans la foret vierge avec votre compagnie, vous etes enfin arrive au temple de Susa-no-o, le dieu de la mer et des orages. Votre unite a ete decimee sur les marches montant a ce lieu, mais vous avez reussi a vous glisser dans l'enceinte sacree du temple, hors d'atteinte de vos ennemis. En tout cas cela ne veut pas dire qu'un de ces fourbes ne tentera pas de vous eliminer pour recuperer a votre place ce que vous etes venu chercher ici. [end if]Le temple est une grande structure octogonale en bois, recouverte a l'interieur de panneaux en palissandre. La plupart des decorations interieures ont disparu au cours des temps, car ce temple a ete abandonne durant plusieurs siecles et vraisemblablement pille. La sortie se trouve au sud. [if player has katana][otherwise] Mais il n'est pas conseille de sortir d'ici tout de suite, desarme comme vous l'etes. [end if]".
ChambreSacree is east from Temple. ChambreSacree is in dedans. The printed name of ChambreSacree is "Chambre sacree". The description of ChambreSacree is "Cette piece a conserve tous ses objets rituels, car elle etait restee fermee sans que personne ne la decouvre durant tout ce temps.".
Parvis is outside from Temple. Parvis is south from Temple.
Parvis is in dehors. The description of parvis is "L'entree du temple se trouve en haut de quelques marches, mais ces marches sont actuellement tachees du sang de vos compagnons qui sont tous tombes sous les coups de vos ennemis. En bas, tout autour du temple, une foret qui semble sans fin. [if player has katana][otherwise] Vous ne devriez pas rester ici, car ils vous attendent egalement pour vous faire subir le meme sort. [end if][if nuit is happening]Il fait nuit. [otherwise]Il fait jour. [end if]".
The DecorationInterieure is backdrop in Dedans.
The printed name of DecorationInterieure is "interieur du temple". Understand "Interieur du temple" or "toit du temple" or "interieur/toit/toiture/sol/tatami/poutres/temple" as DecorationInterieure. The description of DecorationInterieure is "Tout cet espace inspire a la meditation et au travail sur soi-meme.".
The escalier is backdrop in parvis and in foret. Understand "sang/marches/marche/escalier" as escalier.
The description of escalier is "Les marches sont recouvertes du sang de vos compagnons."
Some compagnons are backdrop in dehors.
The description of compagnons is "Des samourais honorables, qui sont tombes sous le nombre et la ruse de vos ennemis de toujours, les ninjas du clan de Daimyo."
Some decorsdehors are backdrop in dehors. The printed name of decorsdehors is "des choses au dehors". The description of decorsdehors is "C'est juste des elements du decor.". Understand "feuillage/palmiers/toit/temple/ombres/arbres" as decorsdehors.
Foret is down from Parvis. Foret is in dehors. Foret is outside from Parvis.
The printed name of Foret is "Foret". The description of foret is "Une clairiere dans la foret.".
Instead of going down from Parvis during Nuit:
say "Un samourai evite toujours d'aller combattre durant la nuit, surtout si ses ennemis sont des adeptes des techniques et des combats nocturnes.".
Instead of going east from Temple when the scarabee is not in cachette, say "Vous ne pouvez pas aller par la."
Chapter 2 - Les petits objets
Section 1 - Les armes
Weapon is a kind of thing.
The armure is a female Weapon. It is worn by the player.
The description of the armure is "Une armure d'un rouge flamboyant, symbole de la famille des Kunitsukami. L'armure est la fierete du samourai, au meme titre que son arme.".
The wakizashi is a Weapon. It is held by the player.
The description of wakizashi is "De la taille d'une longue dague, c'est le compagnon de votre katana. [if katana is in player][otherwise]Quel dommage que vous ayez ete oblige de laisser ce dernier dehors, lorsqu'un ennemi l'a fait sauter de votre poigne. Mais celui-ci, meme s'il a ete forge et trempe par les meilleurs forgerons du village, durant un long mois, semblait sans valeur par rapport a l'arme que vous etes venu chercher en ce lieu.[end if]".
Understand "wakizashi/dague/arme" as wakizashi.
The katana is a weapon in ChambreSacree. Understand "arme/epee/katana/kusanagi/fourreau" as katana.
The description of the katana is "C'est la plus belle arme que vous n'ayez jamais vue, une epee a double tranchant, et pourtant legere, tout en metal argente tirant sur un blanc tres pur. Une epee de roi ! [if katana is magic]Le fourreau de cette epee se trouve a vos cotes, faisant corps avec vous. [otherwise]Dommage qu'il manque son fourreau.[end if]".
The printed name of katana is the "Kusanagi". The indefinite article of katana is "le".
A thing is either magic or normal. The katana is normal.
instead of taking the katana:
if the ninjas are not in foret
begin;
say "Felicitation, vous avez enfin pu vous debarrasser de vos ennemis et mettre la main sur cette arme mythique. ";
move katana to player;
end the game in victory;
play the sound of Intro;
otherwise;
say "Vous avez enfin pu trouver cet arme mythique, mais il vous reste encore a pouvoir rentrer sain et sauf chez vous.";
continue the action;
end if.
Section 2 - La cachette
The panneau is a scenery in Temple. The panneau is a closed container.
Understand "trappe/scene/scenes/decorations/murs/mur/peintures/panneaux/panneau/porte/laque/boite/piedestal/oiseaux/dieu/fuji/bamboux/paysage" or "petite ouverture" as panneau. The panneau is openable.
The cachette is a female container in panneau. It is open.
Understand "cache/cachette/ouverture/ovale/marque" or "marque ovale" as cachette. The description of cachette is "L'ouverture qui est pratiquee dans le panneau est grande comme la main, et une marque ovale se trouve au fond de celle-ci."
Instead of inserting a Weapon into panneau, say "Cela n'est pas fait pour mettre cela."
Instead of inserting a Weapon into cachette, say "Cela n'est pas fait pour mettre cela."
Instead of inserting scarabee into panneau, try inserting scarabee into cachette.
Instead of putting scarabee on cachette, try inserting scarabee into cachette.
When Cage begins:
if the panneau is not closed
begin;
say "Le panneau etant reste ouvert, le scarabee reprend sa liberte et s'envole dans le temple.";
move scarabee to location;
end if.
Table of Decorations
scene
"des oiseaux aux longues pattes dans une riziere, sans doute des herons"
"un homme qui se cache sous une feuille de palmier"
"une boite sur un piedestal"
"un paysage au bord de la mer, avec un bosquet de bamboux au premier plan"
"le Mont-Fuji dans toute sa splendeur"
"une representation epique du dieu Susa-no-o"
Instead of examining panneau:
choose a random row in the table of Decorations;
say "Sur ces panneaux richement decores habillant l'interieur du temple, la laque noir issue du sumac n'a pas ete alteree au cours du temps. Vous voyez sur l'un d'eux une scene representant [scene entry].".
Instead of pushing or searching panneau:
if panneau is not open
begin;
say "Vous trouvez une cache secrete dans un des panneaux en vous faufilant derriere le paravent. La petite trappe coulisse en appuyant dessus lateralement, revelant une ouverture dans le mur.";
change the panneau to open;
otherwise;
continue the action;
end if.
Instead of pulling panneau:
say "Il n'y a pas de prise sur ces panneaux, mais peut-etre est-il possible de les pousser a la place ?".
Instead of opening panneau:
say "[if panneau is open]C'est deja ouvert.[otherwise]Vous ne trouvez pas le moyen d'ouvrir cela ainsi.[end if]".
Instead of closing panneau:
if scarabee is in cachette
begin;
say "Vous entendez un declic et une porte parfaitement cachee dans un des panneaux sur votre droite s'ouvre sur une petite piece lorsque vous manipulez la trappe.";
continue the action;
otherwise;
if panneau is open
begin;
say "Vous refermez le panneau en le faisant coulisser dans l'autre sens.";
now the panneau is closed;
otherwise;
say "Cela n'est pas ouvert.";
end if;
end if.
instead of closing cachette, try closing panneau.
The paravent is a thing in temple. It is fixed in place. The description of paravent is "Un paravent recouvert d'incrustations en nacre, il se trouve assez proche d'un des murs."
Understand "paravent/nacre/incrustations" as paravent.
Instead of pushing or pulling or taking or attacking paravent, say "Il a ete pose la par les pretres de Susa-no-o pour proteger l'intimite du dieu, et cela serait un sacrilege de le deplacer ou de l'abimer."
Instead of turning paravent, say "Un des panneaux qui se trouve derriere a un aspect un peu etrange, comme s'il n'avait pas ete fabrique en meme temps que les autres.".
Instead of looking under paravent, try turning paravent.
Chapter 3 - Les personnages
Section 1 - Le joueur
Instead of examining player:
say "Dans votre glorieuse armure de samourai, vous savez que votre apparence est fiere et determinee. [mission of the player].";
try meditating player.
Section 2 - Le scarabee
The scarabee is an animal in temple.
The printed name of scarabee is "scarabee". Understand "insecte/scarabee" as scarabee. The description of scarabee is "Avec sa petite armure sophistiquee, il vous fait penser a un samourai miniature. Sa couleur est d'un vert vif.".
Table of ScarabeeAction
mouvement
"s'envoler pour se poser un peu plus loin"
"s'eloigner rapidement pour passer sous l'interstice des panneaux"
"disparaitre dans un petit nuage de fumee pour reapparaitre ensuite a un autre endroit"
"s'eloigner rapidement"
Instead of touching or taking scarabee when the armure is worn:
choose a random row in the table of ScarabeeAction;
say "Le scarabee decide de [mouvement entry] et il passe hors d'atteinte.".
Instead of touching or taking scarabee:
say "Sans votre armure, le scarabee ne vous a pas considere comme un ennemi et ne s'est pas effraye de votre presence, aussi vous pouvez le prendre avec vous.";
move scarabee to player.
Instead of meditating armure:
say "Votre armure est terrifiante, tellement terrifiante que meme les gens de votre famille ou vos animaux en ont peur lorsque vous la gardez continuellement sur vous. Vous repensez avec amusement aux samourais novices qui esperent seduires les jeunes filles avec cette armure flamboyante...".
Instead of meditating scarabee when armure is worn:
say "Vous voyez l'image d'un scarabee de votre taille, revetu pourtant d'une armure gigantesque, qui essaye de se defendre tant bien que mal de vos coups.".
Instead of giving armure to scarabee, say "Cet insecte a deja sa propre armure.".
Instead of putting armure on scarabee, try giving armure to scarabee.
Instead of meditating scarabee:
say "Vous voyez l'image d'un scarabee qui vous protege contre vos ennemis.".
Instead of meditating player:
say "Vous vous concentrez sur vous-meme, mais ici cette mission demande que vous meditiez plutot sur ce qui vous est exterieur, si vous voulez la mener a son terme.".
Instead of tying scarabee to katana:
now the katana is magic;
say "Au moment ou vous posez le scarabee sur la garde de l'epee, une flamme verte illumine brievement sa lame, et vous sentez une force surnaturelle prendre possession de vous. Le scarabee disparait alors pour se transformer en un grand fourreau recouvert d'une carapace verte, qui vient se positionner a votre cote tant que vous gardez l'epee avec vous.";
remove scarabee from play.
Instead of putting scarabee on katana, try tying scarabee to the katana.
Instead of putting scarabee on compagnons during nuit:
say "Lorsque vous posez le scarabee sur ce qui fut autrefois l'ame de vos compagnons, une pluie d'etoiles filantes illumine le ciel. Vous avez une pensee emue pour tous ces valeureux combattants, et vous rememorez en une fraction de seconde les meilleurs moments passes avec eux. Vous avez maintenant l'impression qu'ils sont a vos cotes, prets a combattre avec vous, prets a se venger de l'infamie qui leur a ete faite.";
move fantomes to parvis;
remove compagnons from play;
remove scarabee from play.
Instead of putting scarabee on escalier during nuit:
try putting scarabee on compagnons.
Instead of attacking scarabee, say "Vous entendez dans votre tete la voix de votre vieux maitre qui dit : 'La violence n'est pas une solution petit scarabee !'".
Instead of turning scarabee, say "Cela n'a pas lieu d'etre fait.".
Instead of searching scarabee, try taking scarabee.
Section 3 - Les fantomes
Some Fantomes are men. The printed name of fantomes is "fantomes".
The description of fantomes is "Quelques-uns de vos compagnons, revenus mysterieusement a la vie par la magie guerriere.".
Understand "compagnons/fantomes/fantome" as fantomes.
Instead of talking to fantomes, say "Vous essayez de rappeler a vos anciens amis diverses anecdotes les concernant, mais ils ne semblent pas preter attention a vous pour le moment.".
Instead of attacking fantomes, say "Vous ne savez pas quelle force surnaturelle les investi, aussi il ne vaut mieux pas, de plus vous n'avez pas envie d'attaquer vos anciens compagnons Samourai.".
Section 4 - Les Ninjas ennemis
Some ninjas are men in foret. The description of ninjas is "Vos ennemis jures et ceux de la famille Kunitsukami. Des tueurs de l'ombres, rendus invincibles par des pratiques physiques et spirituelles hors-normes."
Understand "ninja/ninjas" as ninjas.
Instead of talking to ninjas, say "L'heure n'est pas a la discussion, ils sont la pour vous eliminer.".
Instead of attacking ninjas:
if CCombat is less than 10
begin;
say "Vous trouvant quasiment desarme, vos ennemis n'ont eu aucun mal a vous vaincre.";
end the game in death;
play the sound of Perdu;
otherwise;
if a random chance of CCombat in 20 succeeds
begin;
say "Puisant vos forces dans toutes vos ressources guerrieres, vous trouvez la force de vaincre vos ennemis. ";
if fantomes are in parvis, say "Vos anciens compagnons ont ete une aide precieuse dans cette tache. ";
if katana is in player, say "L'epee de Kusanagi-no-Tsurugi a egalement arme votre bras d'une magie surnaturelle. Voudrez-vous reellement vous departir d'une telle arme pour donner a votre Shogun ?";
move scarabee to temple;
remove ninjas from play;
remove fantomes from play;
if player has katana, end the game in victory;
play the sound of Intro;
otherwise;
say "Les ninjas du clan ennemi etaient mieux prepares que vous, et ils vous massacrent sans autre forme de proces. Ou peut-etre qu'ils ont eu un peu plus de chance cette fois-ci ?";
End the game in death;
play the sound of Perdu;
end if;
end if.
Chapter 4 - Les verbes specifiques au jeu
Meditating is an action applying to one things.
Carry out Meditating:
say "Vous n'arrivez pas a vous concentrer suffisamment sur ce sujet.".
Understand "mediter sur [someone]" as meditating.
Understand "mediter sur [something]" as meditating.
Instead of meditating panneau:
say "Vous ne voyez que ce que vos yeux voient.".
Instead of meditating paravent:
say "En vous concentrant un peu vous arrivez a voir un homme a l'air grave et avec une longue barbe noire qui medite derriere le paravent. Puis l'image vacille et disparait rapidement.".
Instead of meditating katana:
say "Vous n'avez pas besoin de mediter dessus pour vous rendre compte du formidable pouvoir que cette arme renferme.".
Instead of meditating fantomes:
say "Leur presence est tres subtile, mais leur action peut s'averer tres utile face a vos ennemis.".
Instead of meditating ninjas:
say "Parfois il vaut mieux agir vite plutot que de mediter trop longtemps dans le vide.".
Instead of listening, say "A part quelques bruits provenant de la foret, vous n'entendez plus rien de particulier en ce moment.".
[
Understand the command "attaque" as something new.
Understand the command "take" as something new.
ne fonctionne que pour les verbes anglais]
Attacking it with is an action applying to one thing and one carried thing.
Understand "attack [something] avec [something]" as attacking it with.
Understand "attaque [something] avec [something]" as attacking it with.
[probleme pour utiliser attaquer a la place de attack : you may not supply a second noun]
Instead of attacking the ninjas with katana, try attacking the ninjas.
Instead of attacking the ninjas with wakizashi, try attacking the ninjas.
Going behind is an action applying to one thing.
Understand "go derriere [something]" as going behind.
[ fonctionne ...]
Understand "alller derriere [something]" as going behind.
[ne fonctionne pas...]
Instead of going behind the paravent, try turning paravent.
Chapter 5 - Tests
Test me with "test me1a/test me1b/test me1c"
Test variante with "test me1a/test me2a/test me2b/test me1b"
Test me1a with "x moi/regarder paravent/x panneaux/x scarabee/mediter sur scarabee/mediter sur panneaux/mediter sur armure/mediter sur paravent/enlever armure/prendre le scarabee"
Test me1b with "pousser panneau/mettre scarabee dans l'ouverture/fermer le panneau/aller a droite/prendre l'epee"
Test me1c with "aller a gauche/pousser le panneau/prendre le scarabee/mettre le scarabee sur kusanagi/dormir/mettre l'armure/sortir/descendre/attaquer les ninjas"
Test me2a with "sortir/mettre le scarabee sur les compagnons/entrer/dormir/mettre l'armure/sortir/x fantomes/descendre/attaquer les ninjas"
Test me2b with "monter/entrer/retirer armure/prendre le scarabee"
Chapter 6 - Notes - Not for release
[cat auto.inf | sed -e "s/ s~/ s\'/g" | sed -e "s/ n~/ n\'/g" | sed -e "s/ l~/ l\'/g" | sed -e "s/ c~/ c\'/g" | sed -e "s/ d~/ d\'/g" | sed -e "s/ j~/ j\'/g" | sed -e "s/ m~/ m\'/g" | sed -e "s/ u~/ u\'/g" > auto2.inf
/usr/local/share/inform7/Compilers/inform-6.31-biplatform -kE2SDwv8x +/usr/local/share/inform7/Library/Natural ./auto2.inf -o ./scarabeekatana.z8
]
Include (-
!Extend 'regarder' last
! * 'derriere' noun -> LookUnder;
!Verb 'retirer'
! * held -> Disrobe
!Extend 'attaquer' first
! * noun 'avec' held -> Attack;
-)
